***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*MAR 06, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3472B-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     81.54
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=0.85  VTO=2.18  LEVEL=3  VMAX=1e5  ETA=8.000e-5  nfs=2.5e10  gamma=1.8)
Rd     d1    d2    860m TC=6m,20u 
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66  TBV1=9.35e-4   CJO=5.745e-12  M=2.902e-1  VJ=3.905e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.396e-14  N=1.0000  RS=12.04u  EG=1.05  TT=20n  ikf=5.3701e-2)
Rdiode  d1  21    1.0967e-1 TC=0.8m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   7.084e-12
.MODEL     DGD    D(M=2.904e-1   CJO=7.084e-12   VJ=3.909e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.84798e-11
.ENDS
*$
